"The following variable defines the $3$ intervals of $[0,1]$ on which $\psi$ is linear."
interval={{0,1/6},{1/6,5/6},{5/6,1}}

"This is the definition of $\psi$ on each one of the $3$ intervals."

psi={ Function[x,0], Function[x,(6x-1)/4], Function[x,1]}

"These are the three non-symmetric possibilities of $(\t(u,v), \t(v,w), \t(w,u))$."

taus = {{0,0,0}, {0,1,1}, {1,1,1}}

"The following variable $fh$ will hold $A_L^\psi(u,v,w)$.  The variables $psix1, psix2,psix3$ represent $\psi(x_{LP}(u,v)), \psi(x_{LP}(v,w)), \psi(x_{LP}(w,u))$
respectively, and $tau1, tau2,tau3$ represent $\t(u,v),\t(v,w),\t(w,u)$, respectively"

fh = 
((1-psix1)(1-psix2) + psix1(1-psix2) + (1-psix1)psix2)(x3 (1-tau3) + (1-x3) tau3) + 
((1-psix2)(1-psix3) + psix2(1-psix3) + (1-psix2)psix3)(x1 (1-tau1) + (1-x1) tau1) +
((1-psix3)(1-psix1) + psix3(1-psix1) + (1-psix3)psix1)(x2 (1-tau2) + (1-x2) tau2)

"Similarly we will use the Mathematica variable $fx$ to represent $B_\psi(u,v,w)$."

fx = (1-psix1)(1-psix2)tau3 + (psix1(1-psix2) + (1-psix1)psix2)(1-tau3) +
 (1-psix2)(1-psix3)tau1 + (psix2(1-psix3) + (1-psix2)psix3)(1-tau1) +
(1-psix3)(1-psix1)tau2 + (psix3(1-psix1) + (1-psix3)psix1)(1-tau2)

"Our goal is to prove that $fx \leq 3fh/2$.  To that end we define a function $ToMaximize$ and we will show that it is nonpositive."

ToMaximize = fx - 3fh /2

"The following variable $ToMaximizeijk$ is a function that takes $4$ indices as input, and returns the function $ToMaximize$ with $psix1,psix2,psix3$
replaced by $\psi_i(x_{uv}), \psi_j(x_{vw}), \psi_k(x_{wu})$ where $\psi_1,\psi_2,\psi_3$ correspond to the definition of $\psi$ on the three
intervals on which it is linear, respectively.  The variables $tau1,tau2,tau3$ are substituted by the possibility pointed to by the argument $tauindex$."

ToMaximizeijk = Function[{i,j,k, tauindex},
 ToMaximize /. {psix1 -> psi[[i]][x1], psix2->psi[[j]][x2], psix3->psi[[k]][x3], 
tau1 -> taus[[tauindex]][[1]], tau2 -> taus[[tauindex]][[2]], tau3 -> taus[[tauindex]][[3]]}]

"The following loop tries all posibilities for $i,j,k, tauindex\in \{1,2,3\}$, and for each one computes the maximum of $ToMaximizeijk(i,j,k,tauindex)$
in the polytope defined by the corresponding constraints.  One checks that the maximal value is always $\leq 0$."

For[i=1,i≤3,i++,
For[j=1,j≤3,j++,
For[k=1,k≤3,k++,
For[tauindex = 1, tauindex ≤ 3, tauindex++,
Print["-----------------------------------------------------------------------------------------------------"];
Print["i,j,k,tau = ",i,",",j,",",k,",", taus[[tauindex]]];
Print["Function=",Simplify[ToMaximizeijk[i,j,k,tauindex]]];
polytope = 
{x1≤ interval[[i]][[2]], x1≥interval[[i]][[1]],
x2≤interval[[j]][[2]],x2≥interval[[j]][[1]], 
x3≤interval[[k]][[2]],x3≥interval[[k]][[1]],
x1 ≤ x2 + x3,  x2 ≤ x3 + x1, x3 ≤ x1 + x2};
Print["Polytope=", polytope];
output=Maximize[{ToMaximizeijk[i,j,k,tauindex],polytope}, {x1,x2,x3}];
Print["Maximum=", output[[1]]," obtained at: ",output[[2]]]]]]]