Require Import Coqlib.
Require Import Maps.
Require Import AST.
Require Import Integers.
Require Import Values.
Require Import Events.
Require Import Memory MemReserve.
Require Import Globalenvs.
Require Import Smallstep.
Require Import Op.
Require Import Locations.
Require Import Conventions.
Require Import Values_symbolic.
Require Import Values_symbolictype.
Require Import MemRel.

Abstract syntax

Definition node := positive.

Inductive instruction: Type :=
  | Lop (op: operation) (args: list mreg) (res: mreg)
  | Lload (chunk: memory_chunk) (addr: addressing) (args: list mreg) (dst: mreg)
  | Lgetstack (sl: slot) (ofs: Z) (ty: typ) (dst: mreg)
  | Lsetstack (src: mreg) (sl: slot) (ofs: Z) (ty: typ)
  | Lstore (chunk: memory_chunk) (addr: addressing) (args: list mreg) (src: mreg)
  | Lcall (sg: signature) (ros: mreg + ident)
  | Ltailcall (sg: signature) (ros: mreg + ident)
  | Lbuiltin (ef: external_function) (args: list mreg) (res: list mreg)
  | Lbranch (s: node)
  | Lcond (cond: condition) (args: list mreg) (s1 s2: node)
  | Ljumptable (arg: mreg) (tbl: list node)
  | Lreturn.

Definition bblock := list instruction.

Definition code: Type := PTree.t bblock.

Record function: Type := mkfunction {
  fn_id: ident;
  fn_sig: signature;
  fn_stacksize: Z;
  fn_code: code;
  fn_entrypoint: node;
  fn_stacksize_pos: 0 <= fn_stacksize;
  fn_stacksize_aligned: align fn_stacksize 8 = fn_stacksize
}.

Definition fundef := AST.fundef function.

Definition fid f :=
  match f with
    Internal f => Some (fn_id f)
  | _ => None
  end.

Definition program := AST.program fundef unit.

Definition funsig (fd: fundef) :=
  match fd with
  | Internal f => fn_sig f
  | External ef => ef_sig ef
  end.

Operational semantics

Definition genv := Genv.t fundef unit.
Definition locset := Locmap.t.


Definition call_regs (caller: locset) : locset :=
  fun (l: loc) =>
    match l with
    | R r => caller (R r)
    | S Local ofs ty => Eval Vundef
    | S Incoming ofs ty => caller (S Outgoing ofs ty)
    | S Outgoing ofs ty => Eval Vundef
    end.


Definition return_regs (caller callee: locset) : locset :=
  fun (l: loc) =>
    match l with
    | R r =>
        if In_dec mreg_eq r destroyed_at_call
        then callee (R r)
        else caller (R r)
    | S sl ofs ty => caller (S sl ofs ty)
    end.


Inductive stackframe : Type :=
  | Stackframe:
      forall (f: function) (* calling function *)
        (sp: expr_sym) (* stack pointer in calling function *)
             (ls: locset) (* location state in calling function *)
             (bb: bblock), (* continuation in calling function *)
      stackframe.

Inductive state : Type :=
  | State:
      forall (stack: list stackframe) (* call stack *)
             (f: function) (* function currently executing *)
             (sp: expr_sym) (* stack pointer *)
             (pc: node) (* current program point *)
             (ls: locset) (* location state *)
             (m: mem), (* memory state *)
      state
  | Block:
      forall (stack: list stackframe) (* call stack *)
             (f: function) (* function currently executing *)
             (sp: expr_sym) (* stack pointer *)
             (bb: bblock) (* current basic block *)
             (ls: locset) (* location state *)
             (m: mem), (* memory state *)
      state
  | Callstate:
      forall (stack: list stackframe) (* call stack *)
             (f: fundef) (* function to call *)
             (ls: locset) (* location state of caller *)
             (m: mem), (* memory state *)
      state
  | Returnstate:
      forall (stack: list stackframe) (* call stack *)
             (ls: locset) (* location state of callee *)
             (m: mem), (* memory state *)
      state.


Section RELSEM.

  Variable ge: genv.

  Variable needed_stackspace: ident -> nat .

Definition reglist (rs: locset) (rl: list mreg) : list expr_sym :=
  List.map (fun r => rs (R r)) rl.

Fixpoint undef_regs (rl: list mreg) (rs: locset) : locset :=
  match rl with
    | nil => rs
    | r1::rl => Locmap.set (R r1) (Eval Vundef) (undef_regs rl rs)
  end.

Definition destroyed_by_getstack (s: slot): list mreg :=
  match s with
  | Incoming => temp_for_parent_frame :: nil
  | _ => nil
  end.

Definition find_function (m: mem) (ros: mreg + ident) (rs: locset) : option fundef :=
  match ros with
  | inl r => Genv.find_funct m ge (rs (R r))
  | inr symb =>
      match Genv.find_symbol ge symb with
      | None => None
      | Some b => Genv.find_funct_ptr ge b
      end
  end.



Lemma find_function_lessdef:
  forall m m' ros' ls1 tfd,
   mem_lessdef m m' ->
    find_function m ros' ls1 = Some tfd ->
    find_function m' ros' ls1 = Some tfd.



Definition parent_locset (stack: list stackframe) : locset :=
  match stack with
  | nil => Locmap.init
  | Stackframe f sp ls bb :: stack' => ls
  end.

Inductive step: state -> trace -> state -> Prop :=
  | exec_start_block: forall s f sp pc rs m bb,
      (fn_code f)!pc = Some bb ->
      step (State s f sp pc rs m)
        E0 (Block s f sp bb rs m)
  | exec_Lop:
      forall s f sp op args res bb rs m v rs',
        eval_operation ge sp op (reglist rs args) = Some v ->
        rs' = Locmap.set (R res) v (undef_regs (destroyed_by_op op) rs) ->
        step (Block s f sp (Lop op args res :: bb) rs m)
             E0 (Block s f sp bb rs' m)
  | exec_Lload: forall s f sp chunk addr args dst bb rs m a v rs',
      eval_addressing ge sp addr (reglist rs args) = Some a ->
      Mem.loadv chunk m a = Some v ->
      rs' = Locmap.set (R dst) v (undef_regs (destroyed_by_load chunk addr) rs) ->
      step (Block s f sp (Lload chunk addr args dst :: bb) rs m)
        E0 (Block s f sp bb rs' m)
  | exec_Lgetstack: forall s f sp sl ofs ty dst bb rs m rs',
      rs' = Locmap.set (R dst) (rs (S sl ofs ty)) (undef_regs (destroyed_by_getstack sl) rs) ->
      step (Block s f sp (Lgetstack sl ofs ty dst :: bb) rs m)
        E0 (Block s f sp bb rs' m)
  | exec_Lsetstack: forall s f sp src sl ofs ty bb rs m rs',
      rs' = Locmap.set (S sl ofs ty) (rs (R src)) (undef_regs (destroyed_by_setstack ty) rs) ->
      step (Block s f sp (Lsetstack src sl ofs ty :: bb) rs m)
        E0 (Block s f sp bb rs' m)
  | exec_Lstore: forall s f sp chunk addr args src bb rs m a rs' m',
      eval_addressing ge sp addr (reglist rs args) = Some a ->
      Mem.storev chunk m a (rs (R src)) = Some m' ->
      rs' = undef_regs (destroyed_by_store chunk addr) rs ->
      step (Block s f sp (Lstore chunk addr args src :: bb) rs m)
        E0 (Block s f sp bb rs' m')
  | exec_Lcall: forall s f sp sig ros bb rs m fd,
      find_function m ros rs = Some fd ->
      funsig fd = sig ->
      step (Block s f sp (Lcall sig ros :: bb) rs m)
        E0 (Callstate (Stackframe f sp rs bb :: s) fd rs m)
  | exec_Ltailcall: forall s f sp sig ros bb rs m fd rs' m' m'',
      rs' = return_regs (parent_locset s) rs ->
      find_function m'' ros rs' = Some fd ->
      funsig fd = sig ->
      Mem.free m sp 0 f.(fn_stacksize) = Some m' ->
      release_boxes m' (needed_stackspace (fn_id f)) = Some m'' ->
      step (Block s f (Eval (Vptr sp Int.zero)) (Ltailcall sig ros :: bb) rs m)
        E0 (Callstate s fd rs' m'')
  | exec_Lbuiltin: forall s f sp ef args res bb rs m t vl rs' m',
      external_call' ef ge (reglist rs args) m t vl m' ->
      rs' = Locmap.setlist (map R res) vl (undef_regs (destroyed_by_builtin ef) rs) ->
      step (Block s f sp (Lbuiltin ef args res :: bb) rs m)
         t (Block s f sp bb rs' m')
  | exec_Lbranch: forall s f sp pc bb rs m,
      step (Block s f sp (Lbranch pc :: bb) rs m)
        E0 (State s f sp pc rs m)
  | exec_Lcond: forall s f sp cond args pc1 pc2 bb rs b pc rs' m i,
      eval_condition cond (reglist rs args) = Some b ->
      Mem.mem_norm m b = Vint i ->
      pc = (if (negb (Int.eq i Int.zero)) then pc1 else pc2) ->
      rs' = undef_regs (destroyed_by_cond cond) rs ->
      step (Block s f sp (Lcond cond args pc1 pc2 :: bb) rs m)
        E0 (State s f sp pc rs' m)
  | exec_Ljumptable: forall s f sp arg tbl bb rs m n pc rs',
                       Mem.mem_norm m (rs (R arg)) = (Vint n) ->
      list_nth_z tbl (Int.unsigned n) = Some pc ->
      rs' = undef_regs (destroyed_by_jumptable) rs ->
      step (Block s f sp (Ljumptable arg tbl :: bb) rs m)
        E0 (State s f sp pc rs' m)
  | exec_Lreturn: forall s f sp bb rs m m' m'',
      Mem.free m sp 0 f.(fn_stacksize) = Some m' ->
      release_boxes m' (needed_stackspace (fn_id f)) = Some m'' ->
      step (Block s f (Eval (Vptr sp Int.zero)) (Lreturn :: bb) rs m)
        E0 (Returnstate s (return_regs (parent_locset s) rs) m'')
  | exec_function_internal: forall s f rs m m' m1 sp rs',
      Mem.alloc m 0 f.(fn_stacksize) Normal = Some (m1, sp) ->
      reserve_boxes m1 (needed_stackspace f.(fn_id)) = Some m' ->
      rs' = undef_regs destroyed_at_function_entry (call_regs rs) ->
      step (Callstate s (Internal f) rs m)
        E0 (State s f (Eval (Vptr sp Int.zero)) f.(fn_entrypoint) rs' m')
  | exec_function_external: forall s ef t res rs m rs' m',
      external_call' ef ge (map rs (loc_arguments (ef_sig ef))) m t res m' ->
      rs' = Locmap.setlist (map R (loc_result (ef_sig ef))) res rs ->
      step (Callstate s (External ef) rs m)
         t (Returnstate s rs' m')
  | exec_return: forall f sp rs1 bb s rs m,
      step (Returnstate (Stackframe f sp rs1 bb :: s) rs m)
        E0 (Block s f sp bb rs m).

End RELSEM.


Inductive initial_state (p: program) sg: state -> Prop :=
  | initial_state_intro: forall b f m0,
      let ge := Genv.globalenv p in
      Genv.init_mem fid sg p = Some m0 ->
      Genv.find_symbol ge p.(prog_main) = Some b ->
      Genv.find_funct_ptr ge b = Some f ->
      funsig f = signature_main ->
      initial_state p sg (Callstate nil f (Locmap.init) m0).

Inductive final_state: state -> int -> Prop :=
  | final_state_intro: forall rs m r retcode v,
      loc_result signature_main = r :: nil ->
      rs (R r) = v ->
      Mem.mem_norm m v = Vint retcode ->
      final_state (Returnstate nil rs m) retcode.

Definition semantics (p: program) ns sg :=
  Semantics (fun ge => step ge ns) (initial_state p sg) final_state (Genv.globalenv p).

Operations over LTL

Fixpoint successors_block (b: bblock) : list node :=
  match b with
  | nil => nil (* should never happen *)
  | Ltailcall _ _ :: _ => nil
  | Lbranch s :: _ => s :: nil
  | Lcond _ _ s1 s2 :: _ => s1 :: s2 :: nil
  | Ljumptable _ tbl :: _ => tbl
  | Lreturn :: _ => nil
  | instr :: b' => successors_block b'
  end.